/*
This is an example trigger that can be used with a Salesforce object to prevent survey fatigue. 
 
*/
 
trigger SurveySent on Survey_From_Object__c (before update) {
 
    Set<Contact> contactSetForUpdate = new Set<Contact>();
   
    for (Survey_From_Object__c surveyFromObject : trigger.new) {
   
        // Get the old version of the custom object from trigger.oldMap context variable.
        Survey_From_Object__c oldsurveyFromObject = trigger.oldMap.get(surveyFromObject.Id);
       
        // Compare the old version of the object to the new version.  If the Survey Sent Date Time field has changed, enter the condition.
 
        if (surveyFromObject.Survey_Sent_Date_Time__c != oldsurveyFromObject.Survey_Sent_Date_Time__c) {
       
            // If the custom object has no contact, exit this iteration of the loop.  We won't be able to update a null contact.
            if (surveyFromObject.Contact__c == null) continue;
           
            // Create a new contact instance, set its Id and Custom_Object_Survey_Last_Requested_On__c.  Setting Id the makes querying the contact table unnecessary.
            Contact c = new contact (
                                     Id = surveyFromObject.Contact__c,
                                     Survey_From_Object_Last_Requested_On__c = surveyFromObject.Survey_Sent_Date_Time__c
                                     );
                                     
            // Add the contact to our set.
            contactSetForUpdate.add(c);
        }
    }
   
   
    // Make sure there is something to before performing any DML.  There is no reason to update an empty list of records!
    if (!contactSetForUpdate.isEmpty()) {
   
        // Create a list and add to contacts to it.  DML cannot be performed on sets. 
        List<Contact> contactsForUpdate = New List<Contact>();
        contactsForUpdate.addAll(contactSetForUpdate);
        
        // Update the contact records
        Update(contactsForUpdate);
    }   
}

/*
Unit test for the SurveySent trigger on Survey_From_Object__c
 
*/
 
@isTest
private class TestCustomObjectSurveySent {
 
   
    private static TestMethod void TestSurveySentTrigger() {
   
        contact c = new contact(FirstName = 'Survey', LastName = 'Recipient');
        insert c;
       
        Survey_From_Object__c surveyFromObject = new Survey_From_Object__c(Contact__c = c.id);
        insert surveyFromObject;
       
        // The surveyFromObjectSurveySent trigger runs on update only.
        surveyFromObject.Survey_Sent_Date_Time__c = dateTime.now();
        update surveyFromObject;
       
        c = [SELECT Survey_From_Object_Survey_Last_Requested_On__c FROM Contact WHERE Id = :c.Id];
       
        // The SurveySent trigger copies the survey sent date time on Survey_From_Object__c to the survey last request on field on Contact.  We therefore expect the same values.
        system.assertEquals(surveyFromObject.Survey_Sent_Date_Time__c,
                            c.Survey_From_Object_Survey_Last_Requested_On__c, 'Survey_From_Object_Survey_Last_Requested_On__c on Contact has an unexpected value');
   
    }
}